Como mostrar o dilaog de impressão para selecionar a opção de imprimir quando clicado em "print" da tela do instalador do contrato de licença usando NSIS

votos
0

Como mostrar a caixa de diálogo de impressão para selecionar a opção de imprimir quando clicado em print da tela do instalador do contrato de licença usando NSIS.

Eu quero mostrar a tela abaixo quando clicado em Imprimir a partir da tela do contrato de licença.

Se eu usar o comando abaixo é imprimir diretamente a página sem aparecendo o diálogo de impressão.

ExecShell print $INSTDIR\license.rtf 0

digite

Publicado 19/12/2018 em 14:11
fonte usuário
Em outras línguas...                            


1 respostas

votos
0

Não há nenhum suporte embutido, mas você pode exibir este diálogo comum com o plug-in do sistema:

!include LogicLib.nsh
!define /IfNDef PD_HIDEPRINTTOFILE 0x00100000
!define /IfNDef PD_NOSELECTION 0x00000004
!define /IFNDef PD_USEDEVMODECOPIESANDCOLLATE 0x00040000 ; Just one copy


Function ShowPrintDlg
System::Call '*(p0,p$hwndparent,p0,p0,p,i${PD_HIDEPRINTTOFILE}|${PD_NOSELECTION}|${PD_USEDEVMODECOPIESANDCOLLATE},&i2,&i2,&i2,&i2,&i2,p,p,p,p,p0,p0,p0,p0,&l.r0)p.r1'
System::Call '*$1(ir0)'
System::Call 'COMDLG32::PrintDlg(pr1)i.r0'
${If} $0 <> 0
    System::Call '*$1(p,p,p.r3,p.r4,t""r2)'
    System::Free $1
    System::Call 'KERNEL32::GlobalFree(pr3)'
    System::Call 'KERNEL32::GlobalLock(pr4)p.r1'
    ${If} $1 P<> 0
        System::Call '*$1(&i2,&i2.r2,&i2,&i2)'
        System::Call '*$1(&i$2,&t999.r2)'
        System::Call 'KERNEL32::GlobalUnlock(pr1)'
        System::Call 'KERNEL32::GlobalFree(pr4)'
    ${EndIf}
    MessageBox mb_ok 'User wants to print to "$2"'
${Else}
    System::Free $1
${EndIf}
FunctionEnd

Page InstFiles

Section
Call ShowPrintDlg
SectionEnd
Respondeu 20/12/2018 em 23:16
fonte usuário

Cookies help us deliver our services. By using our services, you agree to our use of cookies. Learn more